フルオンチェーンNFTの幅を広げる「EthFS: Ethereum File System」の概要や使い方について解説

// Three.js(r147)を読み込む例
fileStore.getFile("three-v0.147.0.min.js.gz").read()

contract RoseExample is ERC721 {
    IFileStore public immutable fileStore;

    // ...中略...

    function tokenURI(uint256 tokenId)
        public
        view
        virtual
        override
        returns (string memory)
    {
        return string.concat(
            "data:application/json,%7B%22name%22%3A%22Example%20Rose%22%2C%22animation_url%22%3A%22data%3Atext%2Fhtml%2C%253Cscript%250A%2520%2520type%253D%2522text%252Fjavascript%252Bgzip%2522%250A%2520%2520src%253D%2522data%253Atext%252Fjavascript%253Bbase64%252C",
            fileStore.getFile("three.min.js.gz").read(), // EthFSからthree.jsを読み込む
            "%2522%250A%253E%253C%252Fscript%253E%250A%253Cscript%2520src%253D%2522data%253Atext%252Fjavascript%253Bbase64%252C",
            fileStore.getFile("gunzipScripts.js").read(), // EthFSからgzip展開用のJavaScriptを読み込む
            "%2522%253E%253C%252Fscript%253E%250A%250A%253Cscript%253E%250A%2520%2520var%2520tokenId%2520%253D%2520",
            toString(tokenId),
            "%253B%250A%253C%252Fscript%253E%250A%253Cstyle%253E%250A%2520%2520*%2520%257B%250A%2520%2520%2520%2520margin%253A%25200%253B%250A%2520%2520%2520%2520padding%253A%25200%253B%250A%2520%2520%257D%250A%2520%2520canvas%2520%257B%250A%2520%2520%2520%2520width%253A%2520100%2525%253B%250A%2520%2520%2520%2520height%253A%2520100%2525%253B%250A%2520%2520%257D%250A%253C%252Fstyle%253E%250A%253Cscript%2520src%253D%2522data%253Atext%252Fjavascript%253Bbase64%252C",
            fileStore.getFile("rose.js").read(), // EthFSからROSESのメインコードを読み込む
            "%2522%253E%253C%252Fscript%253E%250A%22%7D"
        );
    }
}

'data:application/json,{"name":"Example Rose","animation_url":"data:text/html,<script type="text/javascript+gzip" src="data:text/javascript;base64,"',
fileStore.getFile("three.min.js.gz").read(), // EthFSからthree.jsを読み込む
'"></script><script src="data:text/javascript;base64,',
fileStore.getFile("gunzipScripts.js").read(), // EthFSからgzip展開用のJavaScriptを読み込む
'"></script><script>var tokenId = ',
toString(tokenId),
';</script><style>* { margin: 0; padding: 0; } canvas { width: 100%; height: 100%; }</style><script src="data:text/javascript;base64,',
fileStore.getFile("rose.js").read(), // EthFSからROSESのメインコードを読み込む
'"></script>"}'

mapping(bytes32 => address) public pointers;　// checksum => SSTORE2のpointer の mapping

function addContent(bytes memory content) public returns (bytes32 checksum, address pointer) {
    checksum = keccak256(content); // ハッシュ値を求めてチェックサムとする
    if (pointers[checksum] != address(0)) {
        return (checksum, pointers[checksum]); // すでにハッシュ値が登録済みであればアップロードしない
    }
    pointer = SSTORE2.write(content); // SSTORE2でデータを保存する
    pointers[checksum] = pointer; // mappingにチェックサムとSSTORE2のpointerを保存する
    emit NewChecksum(checksum, content.length);
    return (checksum, pointer);
}

mapping(string => bytes32) public files; // ファイル名 => File構造体のchecksum の mapping

function createFile(
    string memory filename, // ファイル名
    bytes32[] memory checksums, // 各chunkのチェックサム (ContentStoreにアップロードしたもの)
    bytes memory extraData // ファイルのメタデータ(メディアタイプやライセンス)
) public returns (File memory file) {
    if (files[filename] != bytes32(0)) { // ファイル名が登録済みでないか確認
        revert FilenameExists(filename);
    }
    return _createFile(filename, checksums, extraData);
}

function _createFile(
    string memory filename,
    bytes32[] memory checksums,
    bytes memory extraData
) private returns (File memory file) {
    Content[] memory contents = new Content[](checksums.length);
    // ファイルサイズを計算
    uint256 size = 0;
    for (uint256 i = 0; i < checksums.length; ++i) {
        size += contentStore.contentLength(checksums[i]);
        contents[i] = Content({checksum: checksums[i], pointer: contentStore.getPointer(checksums[i])});
    }
    if (size == 0) {
        revert EmptyFile();
    }
    // File構造体を作成してContentStoreに登録する
    file = File({size: size, contents: contents});
    (bytes32 checksum, ) = contentStore.addContent(abi.encode(file));
    // ファイル名とFile構造体のチェックサムをmappingに保存
    files[filename] = checksum;
    // FileCreatedイベントを発行
    emit FileCreated(filename, checksum, filename, file.size, extraData);
}

struct Content {
    bytes32 checksum; // chunkのチェックサム
    address pointer; // データコントラクトのアドレス
}
struct File {
    uint256 size; // ファイルサイズ
    Content[] contents; // Contentの配列
}

// 例: earth.jpgのメタデータ
{
   "type": "image/jpeg",
   "encoding": "base64",
   "license": "CC0"
}

fileStore.getFile("three.min.js.gz").read()

function getFile(string memory filename) public view returns (File memory file) {
    bytes32 checksum = files[filename]; // ファイル名からチェックサムを取得
    if (checksum == bytes32(0)) {
        revert FileNotFound(filename); // ファイル名が未登録ならエラー
    }
    address pointer = contentStore.pointers(checksum); // チェックサムからSSTORE2のpointerを取得
    if (pointer == address(0)) {
        revert FileNotFound(filename); // チェックサムが未登録ならエラー
    }
    return abi.decode(SSTORE2.read(pointer), (File)); // SSTORE2からFile構造体を読み込む
}

function read(File memory file) view returns (string memory contents) {
    // ファイルの各パーツ(chunk)の配列を取得
    Content[] memory chunks = file.contents;
    assembly {
        let len := mload(chunks) // ヘッダに格納されている配列の長さを取得
        let totalSize := 0x20 // ヘッダの32バイトを最初に追加
        contents := mload(0x40) // free memory pointerから読み込み
        let size
        let chunk
        let pointer

        // chunkの数だけループ
        for { let i := 0 } lt(i, len) { i := add(i, 1) } {
            // i番目のchunk(=Content構造体)を取得
            chunk := mload(add(chunks, add(0x20, mul(i, 0x20))))
            // Content構造体の2番目の要素(pointer)を読み込む
            pointer := mload(add(chunk, 0x20))
            // chunkデータのサイズを取得
            size := sub(extcodesize(pointer), 1)
            // データコントラクトからchunkデータをコピー
            extcodecopy(pointer, add(contents, totalSize), 1, size)
            // トータルサイズを更新
            totalSize := add(totalSize, size)
        }
        // 戻り値(contents)のヘッダにトータルサイズを保存
        mstore(contents, sub(totalSize, 0x20)) 
        // free memory pointerを更新
        mstore(0x40, add(contents, and(add(totalSize, 0x1f), not(0x1f))))
    }
}